@echo off
rem --- '1_swap.cmd' v2.6 by KdL (2020.01.09)

set TIMEOUT=1
set PROJECT=emsx_top
if "%1"=="" color 87&title SWAP for 1chipMSX and Zemmix Neo
pof2pld %PROJECT%.pof %PROJECT%.pld >nul 2>nul
rd /S /Q db >nul 2>nul
rd /S /Q incremental_db >nul 2>nul
del *.done >nul 2>nul
del *.map >nul 2>nul
del *.pin >nul 2>nul
rem.>%PROJECT%.qpf
del *.rpt >nul 2>nul
del *.map.summary >nul 2>nul
del *.sta.summary >nul 2>nul
del *.qdf >nul 2>nul
del /S /Q *.bak >nul 2>nul
if exist %PROJECT%.pof del recovery.pof >nul 2>nul
ren %PROJECT%.pof recovery.pof >nul 2>nul

:zemmixneo
if not exist %PROJECT%_304k.hex.backslash.zemmixneo goto msx2plus
ren %PROJECT%_304k.hex %PROJECT%_304k.hex.backslash.msx2plus
ren %PROJECT%_304k.hex.backslash.zemmixneo %PROJECT%_304k.hex
if exist %PROJECT%.pld ren %PROJECT%.pld %PROJECT%.pld.1chipmsx >nul 2>nul
if exist recovery.pof ren recovery.pof recovery.pof.1chipmsx >nul 2>nul
if exist %PROJECT%.fit.summary ren %PROJECT%.fit.summary %PROJECT%.fit.summary.1chipmsx >nul 2>nul
del "__1chipmsx__"
rem.>"__zemmixneo__"
cd src\peripheral\
ren swioports.vhd swioports.vhd.1chipmsx >nul 2>nul
ren swioports.vhd.japanese swioports.vhd.japanese.1chipmsx >nul 2>nul
ren swioports.vhd.zemmixneo swioports.vhd >nul 2>nul
ren swioports.vhd.japanese.zemmixneo swioports.vhd.japanese >nul 2>nul

if "%1"=="" cls&color 4f&echo.&echo Zemmix Neo is ready to compile!
goto timer

:msx2plus
if not exist %PROJECT%_304k.hex.backslash.msx2plus goto err_msg
ren %PROJECT%_304k.hex %PROJECT%_304k.hex.backslash.zemmixneo
ren %PROJECT%_304k.hex.backslash.msx2plus %PROJECT%_304k.hex
if exist %PROJECT%.pld ren %PROJECT%.pld %PROJECT%.pld.zemmixneo >nul 2>nul
if exist recovery.pof ren recovery.pof recovery.pof.zemmixneo >nul 2>nul
if exist %PROJECT%.fit.summary ren %PROJECT%.fit.summary %PROJECT%.fit.summary.zemmixneo >nul 2>nul
del "__zemmixneo__"
rem.>"__1chipmsx__"
cd src\peripheral\
ren swioports.vhd swioports.vhd.zemmixneo >nul 2>nul
ren swioports.vhd.japanese swioports.vhd.japanese.zemmixneo >nul 2>nul
ren swioports.vhd.1chipmsx swioports.vhd >nul 2>nul
ren swioports.vhd.japanese.1chipmsx swioports.vhd.japanese >nul 2>nul

if "%1"=="" cls&color 1f&echo.&echo 1chipMSX is ready to compile!  ^(default^)
goto timer

:err_msg
if "%1"=="" color f0
echo.&echo '%PROJECT%_304k.hex.backslash.???' not found!

:timer
if "%1"=="" waitfor /T %TIMEOUT% pause >nul 2>nul

:quit
